home *** CD-ROM | disk | FTP | other *** search
/ Aminet 44 / Aminet 44 (2001)(GTI - Schatztruhe)[!][Aug 2001].iso / Aminet / game / misc / CCGames.lha / SPLAT.BAS < prev    next >
BASIC Source File  |  1980-01-01  |  6KB  |  137 lines
  1. 1 RANDOMIZE
  2. 5 PRINT CHR$(26):WIDTH 80
  3. 10 PRINT TAB(33);"SPLAT":PRINT
  4. 20 PRINT TAB(15);"CREATIVE COMPUTING  MORRISTOWN, NEW JERSEY"
  5. 40 PRINT:PRINT:PRINT
  6. 50 DIM A(42)
  7. 95 PRINT "WELCOME TO 'SPLAT' -- THE GAME THAT SIMULATES A PARACHUTE"
  8. 96 PRINT "JUMP.  TRY TO OPEN YOUR CHUTE AT THE LAST POSSIBLE" 
  9. 97 PRINT "MOMENT WITHOUT GOING SPLAT."
  10. 118 PRINT:PRINT:D1=0:V=0:A=0:N=0:M=0:D1=INT(9001*RND(1)+1000)
  11. 119 PRINT "SELECT YOUR OWN TERMINAL VELOCITY (YES OR NO)";:INPUT A1$    
  12. 120 IF LEFT$(A1$,1)="N" GOTO 128
  13. 121 IF LEFT$(A1$,1)<>"Y" THEN PRINT "YES OR NO";:INPUT A1$:GOTO 120
  14. 123 PRINT "WHAT TERMINAL VELOCITY (MI/HR)";:INPUT V1 
  15. 125 V1=V1*(5280/3600):V=V1+((V1*RND(1))/20)-((V1*RND(1))/20):GOTO 135
  16. 128 V1=INT(1000*RND(1))
  17. 130 PRINT "OK.  TERMINAL VELOCITY ="V1"MI/HR"
  18. 131 V1=V1*(5280/3600):V=V1+((V1*RND(1))/20)-((V1*RND(1))/20) 
  19. 135 PRINT: PRINT "WANT TO SELECT ACCELERATION DUE TO GRAVITY (YES OR NO)"; 
  20. 136 INPUT B1$
  21. 140 IF LEFT$(B1$,1)="N" GOTO 150
  22. 141 IF LEFT$(B1$,1)<>"Y" THEN PRINT "YES OR NO";:INPUT B1$:GOTO 140
  23. 143 PRINT "WHAT ACCELERATION (FT/SEC/SEC)";:INPUT A2 
  24. 145 A=A2+((A2*RND(1))/20)-((A2*RND(1))/20):GOTO 205
  25. 150 ON INT(1+(10*RND(1)))GOTO 151,152,153,154,155,156,157,158,159,160 
  26. 151 PRINT"FINE. YOU'RE ON MERCURY. ACCELERATION=12.2 FT/SEC/SEC.":GOTO 161
  27. 152 PRINT"ALL RIGHT. YOU'RE ON VENUS. ACCELERATION=28.3 FT/SEC/SEC.":GOTO 162
  28. 153 PRINT "THEN YOU'RE ON EARTH. ACCELERATION=32.16 FT/SEC/SEC.":GOTO 163 
  29. 154 PRINT"FINE. YOU'RE ON THE MOON. ACCELERATION=5.15 FT/SEC/SEC.":GOTO 164
  30. 155 PRINT"ALL RIGHT. YOU'RE ON MARS. ACCELERATION=12.5 FT/SEC/SEC.":GOTO 165 
  31. 156 PRINT"THEN YOU'RE ON JUPITER. ACCELERATION=85.2 FT/SEC/SEC.":GOTO 166
  32. 157 PRINT"FINE. YOU'RE ON SATURN. ACCELERATION=37.6 FT/SEC/SEC.":GOTO 167
  33. 158 PRINT"ALL RIGHT. YOU'RE ON URANUS. ACCELERATION=33.8 FT/SEC/SEC.":GOTO 168 
  34. 159 PRINT"THEN YOU'RE ON NEPTUNE. ACCELERATION=39.6 FT/SEC/SEC.":GOTO 169
  35. 160 PRINT"FINE. YOU'RE ON THE SUN. ACCELERATION=896 FT/SEC/SEC.":GOTO 170
  36. 161 A2=12.2:GOTO 145 
  37. 162 A2=28.3:GOTO 145 
  38. 163 A2=32.16:GOTO 145
  39. 164 A2=5.15:GOTO 145 
  40. 165 A2=12.5:GOTO 145 
  41. 166 A2=85.2:GOTO 145 
  42. 167 A2=37.6:GOTO 145 
  43. 168 A2=33.8 :GOTO 145
  44. 169 A2=39.6:GOTO 145 
  45. 170 A2=896:GOTO 145
  46. 205 PRINT
  47. 206 PRINT "    ALTITUDE         ="D1"FT" 
  48. 207 PRINT "    TERM. VELOCITY   ="V1"FT/SEC +/-5%"
  49. 208 PRINT "    ACCELERATION     ="A2"FT/SEC/SEC +/-5%"
  50. 210 PRINT:PRINT "SET THE TIMER FOR YOUR FREEFALL." :PRINT
  51. 211 PRINT "HOW MANY SECONDS";:INPUT T
  52. 212 PRINT
  53. 215 PRINT "HERE WE GO."
  54. 217 PRINT
  55. 218 PRINT "TIME (SEC)","DIST TO FALL (FT)" 
  56. 219 PRINT "==========","=================" 
  57. 300 FOR I=0 TO T STEP (T/8)
  58. 310 IF I>V/A GOTO 400
  59. 320 D=D1-((A/2)*I^2) 
  60. 330 IF D<=0 GOTO 1000
  61. 340 PRINT USING "####.##";I;:PRINT "",:PRINT USING "    ####.##";D
  62. 350 NEXT I 
  63. 360 GOTO 500 
  64. 400 PRINT "TERMINAL VELOCITY REACHED AT T PLUS"V/A"SECONDS."
  65. 405 FOR I=I TO T STEP (T/8)
  66. 410 D=D1-((V^2/(2*A))+(V*(I-(V/A)))) 
  67. 420 IF D<=0 GOTO 1010
  68. 430 PRINT USING "####.##";I;:PRINT "",:PRINT USING "    ####.##";D
  69. 440 NEXT I 
  70. 500 PRINT:PRINT CHR$(22);"              ":PRINT "  CHUTE OPEN  ":
  71.     PRINT "              ";:PRINT CHR$(22)
  72. 510 K=0:K1=0 
  73. 550 FOR J=0 TO 42
  74. 555 IF A(J)=0 GOTO 620 
  75. 560 K=K+1
  76. 570 IF D>=A(J) GOTO 600
  77. 580 K1=K1+1
  78. 600 NEXT J 
  79. 610 GOTO 540 
  80. 620 A(J)=D 
  81. 630 IF J>2 THEN 650
  82. 635 PRINT:PRINT "AMAZING!!! NOT BAD FOR YOUR ";
  83. 636 IF J=0 THEN PRINT "1ST ";
  84. 637 IF J=1 THEN PRINT "2ND ";
  85. 638 IF J=2 THEN PRINT "3RD ";
  86. 639 PRINT "SUCCESSFUL JUMP!!!":PRINT:GOTO 2000
  87. 650 IF K-K1<=.1*K GOTO 700 
  88. 660 IF K-K1<=.25*K GOTO 710
  89. 670 IF K-K1<=.5*K GOTO 720 
  90. 680 IF K-K1<=.75*K GOTO 730
  91. 690 IF K-K1<=.9*K GOTO 740 
  92. 695 GOTO 750 
  93. 700 PRINT:PRINT "WOW!  THAT'S SOME JUMPING.  OF THE"K"SUCCESSFUL JUMPS"
  94. 701 PRINT "BEFORE YOURS, ONLY"K-K1"OPENED THEIR CHUTES LOWER THAN" 
  95. 702 PRINT "YOU DID." 
  96. 703 GOTO 2000
  97. 710 PRINT:PRINT "PRETTY GOOD! " K"SUCCESSFUL JUMPS PRECEDED YOURS AND ONLY"
  98. 711 PRINT K-K1" OF THEM GOT LOWER THAN YOU DID BEFORE THEIR CHUTES"
  99. 712 PRINT "OPENED." :GOTO 2000 
  100. 720 PRINT:PRINT "NOT BAD.  THERE HAVE BEEN"K"SUCCESSFUL JUMPS BEFORE YOURS." 
  101. 721 PRINT"YOU WERE BEATEN OUT BY"K-K1"OF THEM.":GOTO 2000  
  102. 730 PRINT:PRINT "CONSERVATIVE, AREN'T YOU?  YOU RANKED ONLY"K-K1"IN THE"
  103. 731 PRINT K"SUCCESSFUL JUMPS BEFORE YOURS.":GOTO 2000
  104. 740 PRINT:PRINT "HUMPH!  DON'T YOU HAVE ANY SPORTING BLOOD?  THERE WERE" 
  105. 741 PRINT K"SUCCESSFUL JUMPS BEFORE YOURS AND YOU CAME IN"K1"JUMPS"
  106. 742 PRINT "BETTER THAN THE WORST.  SHAPE UP!!!":GOTO 2000
  107. 750 PRINT:PRINT "HEY!  YOU PULLED THE RIP CORD MUCH TOO SOON.  "K"SUCCESSFUL"
  108. 751 PRINT "JUMPS BEFORE YOURS AND YOU CAME IN NUMBER"K-K1"!  GET WITH IT!" 
  109. 752 GOTO 2000
  110. 800 PRINT:PRINT "REQUIESCAT IN PACE.":GOTO 1950
  111. 801 PRINT:PRINT "MAY THE ANGEL OF HEAVEN LEAD YOU INTO PARADISE.":GOTO 1950 
  112. 802 PRINT:PRINT "REST IN PEACE.":GOTO 1950
  113. 803 PRINT:PRINT "SON-OF-A-GUN.":GOTO 1950 
  114. 804 PRINT:PRINT "#$%&&%!$":GOTO 1950 
  115. 805 PRINT:PRINT "A KICK IN THE PANTS IS A BOOST IF YOU'RE HEADED RIGHT.":
  116.     GOTO 1950
  117. 806 PRINT:PRINT "HMMM. SHOULD HAVE PICKED A SHORTER TIME.":GOTO 1950 
  118. 807 PRINT:PRINT "MUTTER. MUTTER. MUTTER.":GOTO 1950
  119. 808 PRINT:PRINT "PUSHING UP DAISIES.":GOTO 1950 
  120. 809 PRINT:PRINT "EASY COME, EASY GO.":GOTO 1950  
  121. 1000 PRINT USING "####.##";SQR(2*D1/A);:PRINT "",:
  122.      PRINT "  ";CHR$(22);"   SPLAT   ";CHR$(22)
  123. 1005 ON INT(1+(10*RND(1)))GOTO 800,801,802,803,804,805,806,807,808,809
  124. 1010 PRINT USING "####.##";(V/A)+((D1-(V^2/(2*A)))/V);:PRINT "",:
  125.      PRINT "  ";CHR$(22);"   SPLAT   " ;CHR$(22)
  126. 1020 GOTO 1005
  127. 1950 PRINT:PRINT "I'LL GIVE YOU ANOTHER CHANCE.":GOTO 2000
  128. 2000 PRINT:PRINT "DO YOU WANT TO PLAY AGAIN";:INPUT Z$  
  129. 2001 IF LEFT$(Z$,1)="Y" GOTO 118
  130. 2002 IF LEFT$(Z$,1)="N" GOTO 2005
  131. 2003 PRINT "YES OR NO":GOTO 2000
  132. 2005 PRINT "PLEASE";:INPUT Z$:IF LEFT$(Z$,1)="Y" GOTO 118
  133. 2006 IF LEFT$(Z$,1)<>"N" THEN PRINT "YES OR NO ";:GOTO 2005
  134. 2007 PRINT:PRINT "SSSSSSSSSS.":PRINT:GOTO 2046
  135. 2046 RUN "MENU"
  136. 
  137.